อยากทราบคำสั่ง การติดตั้งfonts Win7

อยากทราบคำสั่ง การติดตั้งfonts Win7

ประมาณว่าเปิด fontsview ตั้งเป็น default

ที่เก็บไฟล์ Fonts\*.ttf
เลือกทั้งหมด แล้วคลิ้กขวา เลือก Install เมื่อมีถาม ว่าต้อง การทับตัีวเก่าที่มีแล้วหรือไม่ ก็กด yes to all ไปเลย

หามาหลายที่แล้วยังไม่เจอเลย รบกวนท่านอาจารย์ช่วยด้วยครับ

จากลิงก์นี้ดูโค้ดที่ล่างสุดครับ

[You must be registered and logged in to see this link.]

ขอบคุณครับ แล้วต้องไปแก้ไขชื่อ ที่เก็บของเราตรงส่วนไหนครัับ

โค๊ด:โปรแกรมติดตั้งฟอนท์ ลองใช้งานดูครับ

ถ้าเรียนรู้ Autoit อย่างจริงจัง จะพัฒนาโปรแกรมอะไร?ขึ้นมาใช้งาน ไม่ใช่เรื่องยาก

Code:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Opt("MustDeclareVars", 1)

Global $guititle = 'Install Fonts Manager'

Local $hForm = GUICreate($guititle, 363, 112, -1, 200)
GUISetIcon(@ProgramFilesDir&'\AutoIt3\Aut2Exe\Icons\AutoIt_Old4.ico', "", $hForm)
WinSetOnTop($guititle, "", 1)
Local $Input = GUICtrlCreateInput("", 16, 32, 249, 21)
GUICtrlSetBkColor(-1, 0xFFFFFF)
GUICtrlCreateLabel("Fonts Dir path", 112, 15, 70, 17)
Local $Btn_sel = GUICtrlCreateButton("Browse", 272, 32, 75, 25, $WS_GROUP)
Local $Btn_ins = GUICtrlCreateButton("Insatll", 128, 72, 75, 25, $WS_GROUP)
GUICtrlSetCursor (-1, 0)
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetState(@SW_SHOW)
TraySetIcon(@ProgramFilesDir&'\AutoIt3\Aut2Exe\Icons\AutoIt_Old4.ico', "")
While 1
   Local $nMsg = GUIGetMsg()
   Switch $nMsg
      Case $GUI_EVENT_CLOSE
         GUIDelete()
         Exit
        Case $Btn_sel
          Local $dialog_text = 'Choose a folder new fonts'
            Local $source_dir = FileSelectFolder($dialog_text, "", "", "", $hForm)
         If @error = 1 Then ContinueLoop
         GUICtrlSetData($Input, $source_dir)
         GUICtrlSetState($Btn_ins, $GUI_ENABLE)
      Case $Btn_ins
            Local $dest_dir = @WindowsDir&'\Fonts'
         Local $chk_err = DirCopy($source_dir, $dest_dir, 1)
         If $chk_err = 1 Then
            MsgBox(64, "", "Installation fonts complete.", 0, $hForm)
            _reset()
         Else
            MsgBox(48, "Error!", "Cannot install fonts.", 0, $hForm)
              _reset()
         EndIf
   EndSwitch
WEnd

Func _reset()
   GUICtrlSetData($Input, "")
   GUICtrlSetState($Btn_ins, $GUI_DISABLE)
EndFunc

แก้ไขตามที่ผมคอมเมนต์ไว้ครับ

Code:

InstallFont("C:\fonts\*.*") ;เปลี่ยนตำแหน่งที่เก็บ fonts สำหรับติดตั้ง

Func InstallFont($sSourceFile, $sFontDescript="", $sFontsPath="")
    Local Const $HWND_BROADCAST = 0xFFFF
    Local Const $WM_FONTCHANGE = 0x1D

    If $sFontsPath = "" Then $sFontsPath = @WindowsDir & "\fonts"

    Local $sFontName = StringRegExpReplace($sSourceFile, "^.*\\", "")
    If Not FileCopy($sSourceFile, $sFontsPath & "\" & $sFontName, 1) Then Return SetError(1, 0, 0)

    Local $hSearch = FileFindFirstFile($sSourceFile)
    Local $iFontIsWildcard = StringRegExp($sFontName, "\*|\?")
    Local $aRet, $hGdi32_DllOpen = DllOpen("gdi32.dll")

    If $hSearch = -1 Then Return SetError(2, 0, 0)
    If $hGdi32_DllOpen = -1 Then Return SetError(3, 0, 0)

    While 1
        $sFontName = FileFindNextFile($hSearch)
        If @error Then ExitLoop

        If $iFontIsWildcard Then $sFontDescript = StringRegExpReplace($sFontName, "\.[^\.]*$", "")

        $aRet = DllCall($hGdi32_DllOpen, "Int", "AddFontResource", "str", $sFontsPath & "\" & $sFontName)
        If IsArray($aRet) And $aRet[0] > 0 Then
            RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts", _
                $sFontDescript, "REG_SZ", $sFontsPath & "\" & $sFontName)
        EndIf
    WEnd

    DllClose($hGdi32_DllOpen)
    DllCall("user32.dll", "Int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_FONTCHANGE, "int", 0, "int", 0)
    Return 1
EndFunc

ขอบคุณทุกท่านครับ ขอไปลองก่อนครับ